Aktuelle Zeit: 28. März 2024 20:51

Alle Zeiten sind UTC + 1 Stunde




 Seite 1 von 1 [ 2 Beiträge ] 
Autor Nachricht
 Betreff des Beitrags: "reverse" Hotlink for modes
BeitragVerfasst: 18. März 2008 00:02 
Administrator
Benutzeravatar

Registriert: 17. März 2008 13:32
Beiträge: 96
Wohnort: NRW, Germany
;;; Can be modified
; the color for the display of the text to click on
alias -l c { !return $color(notify) }
;; On or off settings
;; 1 on, 0 off
; underlined?
alias -l u { !return 1 }
; colored?
alias -l k { !return 1 }
; bold?
alias -l b { !return 0 }
; italic?
alias -l i { !return 0 }
; the text behind the rawmode to click on make sure it has at least one char and no space (char 32)
alias -l t { !return reverse }
; The Prefix, the last char should not be allowed for nicknames or modes!
; Default: *
; Example: Modechange:
alias -l p { !return * }
; Modechange text, don't leave it empty
; Default: sets mode:
; Example: changes the chanmodes:
alias -l m { !return sets mode: }
; Note: As soon as you change something the old "reverse" links to click on won't work


;;; Don't modify
; lastarg alias
alias -l l { !var %p = $iif($prop,$prop,32) | !return $gettok($$1-,$numtok($1-,%p),%p) }
; required for customization
alias -l z { !return $calc($numtok($m,32)+$1) }
; Text alias
alias -l r {
  !return $iif($u,$chr(31)) $+ $&
    $iif($k,$+($chr(3),$c)) $+ $&
    $iif($i,$chr(29)) $+ $&
    $iif($b,$chr(2)) $+ $&
    $t $+ $&
    $chr(15)
}
on ^*:HOTLINK:$($strip($+(*,$r,*)),2):#:{
  var %h = $gettok($hotline,2-,$asc($right($p,1)))
  if ($r != $l($hotline)) || ($gettok(%h,$+(2-,$z(1)),32) != $m) {
    !halt
  }
}
on *:HOTLINK:$($strip($+(*,$r,*)),2):#:{
  !var %m = $gettok($hotline,2-,$asc($right($p,1)))
  !var %mode = $gettok(%m,$z(2),32)
  !var %chars = $remove($gettok(%m,$+($z(3),-),32),$r)
  !mode # $replacex(%mode,+,-,-,+) %chars
}
on ^*:rawmode:#:{ !haltdef | !echo $color(mode) -t # $p $nick $m $1- $r }



_________________
one step closer to world domination
Cyberscripters Administrator/Founder
   
 
 Betreff des Beitrags: Re: "reverse" Hotlink for modes
BeitragVerfasst: 6. November 2011 06:05 
Administrator
Benutzeravatar

Registriert: 17. März 2008 13:32
Beiträge: 96
Wohnort: NRW, Germany
Updated.
Added customization.



_________________
one step closer to world domination
Cyberscripters Administrator/Founder
   
 
Beiträge der letzten Zeit anzeigen:  Sortiere nach  
 Seite 1 von 1 [ 2 Beiträge ] 

Alle Zeiten sind UTC + 1 Stunde


Wer ist online?

Mitglieder in diesem Forum: 0 Mitglieder


Du darfst keine neuen Themen in diesem Forum erstellen.
Du darfst keine Antworten zu Themen in diesem Forum erstellen.
Du darfst deine Beiträge in diesem Forum nicht ändern.
Du darfst deine Beiträge in diesem Forum nicht löschen.
Du darfst keine Dateianhänge in diesem Forum erstellen.

Suche nach:
Gehe zu:  

cron